前回はBluetoothでLチカをやってみました。
今回はSDカードの読み書きを試してみましょう。
目次
SDカードについて
ESP32-S3にSDカードを接続して読み書きするには以下の2種類の方法があります。
- SPIインターフェースを使用した方法 4本のI/Oピンを使用してSDカードに通信する方式です。
- SDMMCインターフェースを使用した方法 1ビットバスモードと4ビットバスモードがあります。
- 1ビットバスモードは3本のI/Oピンを使用してSDカードに通信します。
- 4ビットバスモードは6本のI/Oピンを使用してSDカードに通信します。
上記の3つの方法のいずれでもSDカードを使用することができますが、アクセス速度に差があります。
- SDMMCの4ビットバスモード がSDカードの読み書きにおいて最も高速です。
- SDMMCの1ビットバスモード は4ビットバスモードと比較して約80％の速度です。
- SPIインターフェース は最も低速で、SDMMCの4ビットバスモードの約50%の速度になります。
通常は、SDMMCの1ビットバスモードでの接続が推奨されます。このモードでは、少ないI/Oピン数で十分な性能と速度でSDカードにアクセスすることができます。
SDカードのフォーマット
チュートリアルを始める前に、空のSDカードにドライブレター（ドライブ名）を割り当てて、フォーマットする必要があります。このためには、カードリーダーとSDカードが必要です。あらかじめご用意ください。以下では、異なるオペレーティングシステム上での操作手順をご案内します。お使いのコンピュータに合った方法を選んでください。
１．SDカードをカードリーダーに挿入し、カードリーダーをパソコンに接続します。
２．Windowsの検索ボックスに「ハードディスク」と入力し、「ハード ディスク パーティションの作成とフォーマット」を選択します。
新規に開いたウィンドウで、1GB程度の未割り当て領域を探します。
対象の領域を右クリックして『新しいシンプルボリューム』を選択してください。
次へ進みます
『ボリュームサイズの指定』画面では、特に修正せずに次へ進みます
ドライブ文字の割当も特に変更せずに次へ進みます
『パーティションのフォーマット』画面では、『ボリュームラベル』を『SD』として次に進みます。
完了ボタンを押します
少し待つとフォーマットが完了します。
コード
/**********************************************************************
Filename : SDMMC Test
Description : The SD card is accessed using the SDMMC one-bit bus
Auther : www.freenove.com
Modification: 2022/10/28
**********************************************************************/
#include "sd_read_write.h"
#include "SD_MMC.h"
#define SD_MMC_CMD 38 //Please do not modify it.
#define SD_MMC_CLK 39 //Please do not modify it.
#define SD_MMC_D0 40 //Please do not modify it.
void setup(){
Serial.begin(115200);
SD_MMC.setPins(SD_MMC_CLK, SD_MMC_CMD, SD_MMC_D0);
if (!SD_MMC.begin("/sdcard", true, true, SDMMC_FREQ_DEFAULT, 5)) {
Serial.println("Card Mount Failed");
return;
}
uint8_t cardType = SD_MMC.cardType();
if(cardType == CARD_NONE){
Serial.println("No SD_MMC card attached");
return;
}
Serial.print("SD_MMC Card Type: ");
if(cardType == CARD_MMC){
Serial.println("MMC");
} else if(cardType == CARD_SD){
Serial.println("SDSC");
} else if(cardType == CARD_SDHC){
Serial.println("SDHC");
} else {
Serial.println("UNKNOWN");
}
uint64_t cardSize = SD_MMC.cardSize() / (1024 * 1024);
Serial.printf("SD_MMC Card Size: %lluMB\n", cardSize);
listDir(SD_MMC, "/", 0);
createDir(SD_MMC, "/mydir");
listDir(SD_MMC, "/", 0);
removeDir(SD_MMC, "/mydir");
listDir(SD_MMC, "/", 2);
writeFile(SD_MMC, "/hello.txt", "Hello ");
appendFile(SD_MMC, "/hello.txt", "World!\n");
readFile(SD_MMC, "/hello.txt");
deleteFile(SD_MMC, "/foo.txt");
renameFile(SD_MMC, "/hello.txt", "/foo.txt");
readFile(SD_MMC, "/foo.txt");
testFileIO(SD_MMC, "/test.txt");
Serial.printf("Total space: %lluMB\r\n", SD_MMC.totalBytes() / (1024 * 1024));
Serial.printf("Used space: %lluMB\r\n", SD_MMC.usedBytes() / (1024 * 1024));
}
void loop(){
delay(10000);
}
プログラムのロジックとして難しいところは無いと思いますが、あまり聞き慣れない言葉としては『Dir』でしょうか。『ディレクトリ』の略ですがフォルダのことですね。コマンドプロンプトを使う人やUNIX系のOSを使ったことがある人ならご存知だと思います。その他はリスト・クリエイト・ライト・アペンド・リード・デリート・リネームと知ってる単語ばかりだと思うので、そのままの処理ですね。これらの関数はfreenoveさんが用意してくれているものです。実際に何をやっているかちょっと覗いてみましょう。
ソースコードと同じディレクトリにある『sd_read_write.cpp』というファイルです。
#include "sd_read_write.h"
void listDir(fs::FS &fs, const char * dirname, uint8_t levels){
Serial.printf("Listing directory: %s\n", dirname);
File root = fs.open(dirname);
if(!root){
Serial.println("Failed to open directory");
return;
}
if(!root.isDirectory()){
Serial.println("Not a directory");
return;
}
File file = root.openNextFile();
while(file){
if(file.isDirectory()){
Serial.print(" DIR : ");
Serial.println(file.name());
if(levels){
listDir(fs, file.path(), levels -1);
}
} else {
Serial.print(" FILE: ");
Serial.print(file.name());
Serial.print(" SIZE: ");
Serial.println(file.size());
}
file = root.openNextFile();
}
}
void createDir(fs::FS &fs, const char * path){
Serial.printf("Creating Dir: %s\n", path);
if(fs.mkdir(path)){
Serial.println("Dir created");
} else {
Serial.println("mkdir failed");
}
}
void removeDir(fs::FS &fs, const char * path){
Serial.printf("Removing Dir: %s\n", path);
if(fs.rmdir(path)){
Serial.println("Dir removed");
} else {
Serial.println("rmdir failed");
}
}
void readFile(fs::FS &fs, const char * path){
Serial.printf("Reading file: %s\n", path);
File file = fs.open(path);
if(!file){
Serial.println("Failed to open file for reading");
return;
}
Serial.print("Read from file: ");
while(file.available()){
Serial.write(file.read());
}
}
void writeFile(fs::FS &fs, const char * path, const char * message){
Serial.printf("Writing file: %s\n", path);
File file = fs.open(path, FILE_WRITE);
if(!file){
Serial.println("Failed to open file for writing");
return;
}
if(file.print(message)){
Serial.println("File written");
} else {
Serial.println("Write failed");
}
}
void appendFile(fs::FS &fs, const char * path, const char * message){
Serial.printf("Appending to file: %s\n", path);
File file = fs.open(path, FILE_APPEND);
if(!file){
Serial.println("Failed to open file for appending");
return;
}
if(file.print(message)){
Serial.println("Message appended");
} else {
Serial.println("Append failed");
}
}
void renameFile(fs::FS &fs, const char * path1, const char * path2){
Serial.printf("Renaming file %s to %s\n", path1, path2);
if (fs.rename(path1, path2)) {
Serial.println("File renamed");
} else {
Serial.println("Rename failed");
}
}
void deleteFile(fs::FS &fs, const char * path){
Serial.printf("Deleting file: %s\n", path);
if(fs.remove(path)){
Serial.println("File deleted");
} else {
Serial.println("Delete failed");
}
}
void testFileIO(fs::FS &fs, const char * path){
File file = fs.open(path);
static uint8_t buf[512];
size_t len = 0;
uint32_t start = millis();
uint32_t end = start;
if(file){
len = file.size();
size_t flen = len;
start = millis();
while(len){
size_t toRead = len;
if(toRead > 512){
toRead = 512;
}
file.read(buf, toRead);
len -= toRead;
}
end = millis() - start;
Serial.printf("%u bytes read for %u ms\r\n", flen, end);
file.close();
} else {
Serial.println("Failed to open file for reading");
}
file = fs.open(path, FILE_WRITE);
if(!file){
Serial.println("Failed to open file for writing");
return;
}
size_t i;
start = millis();
for(i=0; i<2048; i++){
file.write(buf, 512);
}
end = millis() - start;
Serial.printf("%u bytes written for %u ms\n", 2048 * 512, end);
file.close();
}
ファイルの操作は開いて、処理して、閉じるというのが基本的な所作です。閉じ忘れないように気をつけましょう。このプログラムを応用すれば、ログファイルを残したりもできますね。デバッグがはかどります。センサーのデータをCSVで保存してもいいですね。横道にそれますが、センサーデータはInfluxDBに放り込むのが扱いやすくて良いと思います。
次回はmp3プレイヤーを作ってみましょう。
コメント